provider-service/flake.nix

{
  description = "Provider Service - Phoenix/Commanded CQRS/ES service";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        beamPackages = pkgs.beamPackages;
        pname = "provider_service";
        version = "1.0.0";
        mixFodDeps = beamPackages.fetchMixDeps {
          inherit pname version;
          src = pkgs.lib.cleanSource ./.;
          sha256 = "sha256-NMcH0z3ME4pCFXpKBK+GjBR6Fkv0wNeQcMlQFDxNLFo=";
        };
        package = beamPackages.mixRelease {
          inherit pname version mixFodDeps;
          src = pkgs.lib.cleanSource ./.;
          meta = {
            mainProgram = "provider_service";
          };
          removeCookie = false;
        };
        dockerImage = pkgs.dockerTools.buildLayeredImage {
          name = "provider_service";
          contents = [ package pkgs.bashInteractive pkgs.busybox pkgs.shadow ];
          config = {
            Cmd = [ "${package}/bin/provider_service" "start" ];
          };
        };
      in
      {
        packages.default = package;
        packages.dockerImage = dockerImage;
        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            elixir
            elixir-ls
            kubernetes-helm
            git
          ];
        };
      }
    );
}