workload-service/flake.nix

{
  description = "Workload Service - Elixir/Commanded CQRS/ES service";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        beamPackages = pkgs.beamPackages;
        pname = "workload_service";
        version = "1.0.0";
        mixFodDeps = beamPackages.fetchMixDeps {
          inherit pname version;
          src = ./.;
          sha256 = "sha256-jGAGD/OQj8UcwPPrFjjMhzRhh3ezRQnsD1nnGvvYw38=";
        };
        package = beamPackages.mixRelease {
          inherit pname version mixFodDeps;
          src = ./.;
          meta = {
            mainProgram = "workload_service";
          };
          removeCookie = false;
        };
        dockerImage = pkgs.dockerTools.buildLayeredImage {
          name = "workload_service";
          contents = [ package pkgs.bashInteractive pkgs.busybox pkgs.shadow ];
          config = {
            Cmd = [ "${package}/bin/workload_service" "start" ];
          };
        };
      in
      {
        packages.default = package;
        packages.dockerImage = dockerImage;
        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            elixir
            elixir-ls
            kubernetes-helm
            git
            nodejs
          ];
        };
      }
    );
}