zitadel-k8s-operator/build/flake.nix

{
  description = "Zitadel K8s Operator";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        package = pkgs.buildGoModule {
          pname = "zitadel-k8s-operator";
          version = "0.0.0";
          src = ../.;
          doCheck = false;
          vendorHash = "sha256-Ngn1hcOFZP6NivtJfNNafbyg4u4Ti4gr+XUs6KrYgf8=";
          installPhase = ''
            runHook preInstall

            mkdir -p $out/bin
            dir="$GOPATH/bin"
            [ -e "$dir" ] && cp -r $dir/cmd $out/manager

            runHook postInstall
          '';
        };
        dockerPackage = pkgs.dockerTools.buildImage {
          name = "zitadel-k8s-operator";
          fromImageName = "gcr.io/distroless/static";
          fromImageTag = "nonroot";
          copyToRoot = pkgs.buildEnv {
            name = "operator";
            paths = [ package ];
            pathsToLink = [ "/" ];
          };
          config = {
            Cmd = [ "/manager" ];
            WorkingDir = "/";
            User = "65532:65532";
          };
        };
      in
      with pkgs;
      {
        packages.default = package;
        packages.dockerImage = dockerPackage;
        devShells.default = mkShell {
          buildInputs = [
            nixfmt
            gopls
            operator-sdk
            go
          ];
        };
      }
    );
}